[Master] - Slice 641591: EUDR Certificate Capture for Items

src/Apps/W1/Sustainability/app/src/Certificate/SustItem.TableExt.al

@@ -5,7 +5,9 @@ using Microsoft.Inventory.Tracking;
 using Microsoft.Sustainability.Account;
 using Microsoft.Sustainability.Codes;
 using Microsoft.Sustainability.EPR;
+using Microsoft.Sustainability.EUDR;
 using Microsoft.Sustainability.Setup;
+using System.Utilities;
 
 tableextension 6220 "Sust. Item" extends Item
 {
@@ -264,6 +266,24 @@ tableextension 6220 "Sust. Item" extends Item
             CalcFormula = lookup("Product Classification Code".Name where("Code" = field("Product Classification Code"),
                                                                           "Type" = field("Product Classification Type")));
         }
+        field(6238; "EUDR Relevant"; Boolean)
+        {
+            Caption = 'EUDR Relevant';
+            ToolTip = 'Specifies that the item is subject to the EU Deforestation Regulation and that certification details must be tracked per lot.';
+            DataClassification = CustomerContent;
+
+            trigger OnValidate()
+            begin
+                if Rec."EUDR Relevant" then
+                    CheckAndAssignEUDRItemTrackingCode();
+            end;
+        }
+        field(6239; "EUDR Commodity"; Enum "EUDR Commodity")
+        {
+            Caption = 'EUDR Commodity';
+            ToolTip = 'Specifies the regulated EUDR commodity category for the item, such as cattle, cocoa, coffee, oil palm, rubber, soya, or wood.';
+            DataClassification = CustomerContent;
+        }
 #pragma warning restore PTE0002
         field(6250; "Carbon Tracking Method"; Enum "Sust. Carbon Tracking Method")
         {
@@ -283,6 +303,10 @@ tableextension 6220 "Sust. Item" extends Item
             begin
                 if Rec."Carbon Tracking Method" = Rec."Carbon Tracking Method"::Specific then
                     ErrorIfSpecificCarbonTrackingLacksItemTracking();
+
+                if Rec."EUDR Relevant" then
+                    if not IsEUDRItemTrackingCode() then
+                        Rec.TestField("EUDR Relevant", false);
             end;
         }
     }
@@ -291,6 +315,8 @@ tableextension 6220 "Sust. Item" extends Item
         SustainabilitySetup: Record "Sustainability Setup";
         AtLeastOneNonZeroEmissionValueErr: Label '%1, %2, %3 cannot all be zero. Please provide at least one non-zero value.', Comment = '%1, %2 , %3 = Field Caption';
         SpecificCarbonTrackingRequiresTrackingErr: Label 'The %1 is set to %2, which requires serial or lot-specific tracking to calculate per-unit emissions. Set up an %3 with serial or lot-specific tracking for this item.', Comment = '%1 = Carbon Tracking Method field caption, %2 = Carbon Tracking Method value (Specific), %3 = Item Tracking Code field caption';
+        EUDRAssignItemTrackingCodeQst: Label 'You cannot enable %1 because the current value in %3 is not valid for this %2.\\Choose a value where %4, %5, and %6 are enabled.\\ Do you want to update %3?', Comment = '%1 = EUDR Relevant field caption, %2 = Item table caption, %3 = Item Tracking Code field caption, %4 = Lot Specific Tracking field caption, %5 = Lot Info. Inbound Must Exist field caption, %6 = Lot Info. Outbound Must Exist field caption';
+        EUDRItemTrackingCodeErr: Label 'You cannot enable %1 because the current value in %3 is not valid for this %2.\\Choose a value where %4, %5, and %6 are enabled.', Comment = '%1 = EUDR Relevant field caption, %2 = Item table caption, %3 = Item Tracking Code field caption, %4 = Lot Specific Tracking field caption, %5 = Lot Info. Inbound Must Exist field caption, %6 = Lot Info. Outbound Must Exist field caption';
 
     local procedure UpdateCertificateInformation()
     var
@@ -339,4 +365,67 @@ tableextension 6220 "Sust. Item" extends Item
         Item.Validate("Default CH4 Emission", 0);
         Item.Validate("Default CO2 Emission", 0);
     end;
+
+    local procedure CheckAndAssignEUDRItemTrackingCode()
+    var
+        ItemTrackingCode: Record "Item Tracking Code";
+        ConfirmManagement: Codeunit "Confirm Management";
+    begin
+        Rec.TestField(Type, Type::Inventory);
+
+        if IsEUDRItemTrackingCode() then
+            exit;
+
+        if not ConfirmManagement.GetResponseOrDefault(
+            StrSubstNo(
+                EUDRAssignItemTrackingCodeQst,
+                Rec.FieldCaption("EUDR Relevant"),
+                Rec.TableCaption(),
+                Rec.FieldCaption("Item Tracking Code"),
+                ItemTrackingCode.FieldCaption("Lot Specific Tracking"),
+                ItemTrackingCode.FieldCaption("Lot Info. Inbound Must Exist"),
+                ItemTrackingCode.FieldCaption("Lot Info. Outbound Must Exist")),
+            false)
+        then
+            Error(EUDRItemTrackingCodeErr, Rec.FieldCaption("EUDR Relevant"), Rec.TableCaption(), Rec.FieldCaption("Item Tracking Code"), ItemTrackingCode.FieldCaption("Lot Specific Tracking"), ItemTrackingCode.FieldCaption("Lot Info. Inbound Must Exist"), ItemTrackingCode.FieldCaption("Lot Info. Outbound Must Exist"));
+
+        AssignEUDRItemTrackingCode();
+
+        if not IsEUDRItemTrackingCode() then
+            Error(EUDRItemTrackingCodeErr, Rec.FieldCaption("EUDR Relevant"), Rec.TableCaption(), Rec.FieldCaption("Item Tracking Code"), ItemTrackingCode.FieldCaption("Lot Specific Tracking"), ItemTrackingCode.FieldCaption("Lot Info. Inbound Must Exist"), ItemTrackingCode.FieldCaption("Lot Info. Outbound Must Exist"));
+    end;
+
+    local procedure IsEUDRItemTrackingCode(): Boolean
+    var
+        ItemTrackingCode: Record "Item Tracking Code";
+    begin
+        if Rec."Item Tracking Code" = '' then
+            exit(false);
+
+        if not ItemTrackingCode.Get(Rec."Item Tracking Code") then
+            exit(false);
+
+        exit(
+            ItemTrackingCode."Lot Specific Tracking" and
+            ItemTrackingCode."Lot Info. Inbound Must Exist" and
+            ItemTrackingCode."Lot Info. Outbound Must Exist");
+    end;
+
+    local procedure AssignEUDRItemTrackingCode()
+    var
+        ItemTrackingCode: Record "Item Tracking Code";
+        ItemTrackingCodes: Page "Item Tracking Codes";
+    begin
+        ItemTrackingCode.SetRange("Lot Specific Tracking", true);
+        ItemTrackingCode.SetRange("Lot Info. Inbound Must Exist", true);
+        ItemTrackingCode.SetRange("Lot Info. Outbound Must Exist", true);
+        ItemTrackingCodes.SetTableView(ItemTrackingCode);
+        ItemTrackingCodes.LookupMode(true);
+
+        if ItemTrackingCodes.RunModal() <> Action::LookupOK then
+            Error(EUDRItemTrackingCodeErr, Rec.FieldCaption("EUDR Relevant"), Rec.TableCaption(), Rec.FieldCaption("Item Tracking Code"), ItemTrackingCode.FieldCaption("Lot Specific Tracking"), ItemTrackingCode.FieldCaption("Lot Info. Inbound Must Exist"), ItemTrackingCode.FieldCaption("Lot Info. Outbound Must Exist"));
+
+        ItemTrackingCodes.GetRecord(ItemTrackingCode);
+        Rec.Validate("Item Tracking Code", ItemTrackingCode.Code);
+    end;
 }

src/Apps/W1/Sustainability/app/src/Certificate/SustItemCard.PageExt.al

@@ -128,6 +128,14 @@ pageextension 6222 "Sust. Item Card" extends "Item Card"
                 {
                     ApplicationArea = Basic, Suite;
                 }
+                field("EUDR Relevant"; Rec."EUDR Relevant")
+                {
+                    ApplicationArea = ItemTracking;
+                }
+                field("EUDR Commodity"; Rec."EUDR Commodity")
+                {
+                    ApplicationArea = ItemTracking;
+                }
                 group("Product Classification")
                 {
                     Caption = 'Product Classification';

src/Apps/W1/Sustainability/app/src/EUDR/EUDRCommodity.Enum.al

@@ -0,0 +1,43 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.Sustainability.EUDR;
+
+enum 6234 "EUDR Commodity"
+{
+    Extensible = false;
+
+    value(0; " ")
+    {
+        Caption = ' ';
+    }
+    value(1; Cattle)
+    {
+        Caption = 'Cattle';
+    }
+    value(2; Cocoa)
+    {
+        Caption = 'Cocoa';
+    }
+    value(3; Coffee)
+    {
+        Caption = 'Coffee';
+    }
+    value(4; "Oil palm")
+    {
+        Caption = 'Oil palm';
+    }
+    value(5; Rubber)
+    {
+        Caption = 'Rubber';
+    }
+    value(6; Soya)
+    {
+        Caption = 'Soya';
+    }
+    value(7; Wood)
+    {
+        Caption = 'Wood';
+    }
+}

src/Apps/W1/Sustainability/app/src/EUDR/EUDRLotInfoTrackingMgmt.Codeunit.al

@@ -0,0 +1,42 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.Sustainability.EUDR;
+
+using Microsoft.Inventory.Tracking;
+using Microsoft.Purchases.Document;
+
+codeunit 6288 "EUDR Lot Info. Tracking Mgmt"
+{
+    SingleInstance = true;
+
+    var
+        CurrentCountryRegionCode: Code[10];
+
+    internal procedure SetCountryRegionCode(TrackingSpecification: Record "Tracking Specification")
+    var
+        PurchaseHeader: Record "Purchase Header";
+    begin
+        if TrackingSpecification."Source Type" = 0 then
+            exit;
+
+        if TrackingSpecification."Source Type" <> Database::"Purchase Line" then begin
+            ClearCountryRegionCode();
+            exit;
+        end;
+
+        if PurchaseHeader.Get(Enum::"Purchase Document Type".FromInteger(TrackingSpecification."Source Subtype"), TrackingSpecification."Source ID") then
+            CurrentCountryRegionCode := PurchaseHeader."Buy-from Country/Region Code";
+    end;
+
+    internal procedure GetCurrentCountryRegionCode(): Code[10]
+    begin
+        exit(CurrentCountryRegionCode);
+    end;
+
+    internal procedure ClearCountryRegionCode()
+    begin
+        Clear(CurrentCountryRegionCode);
+    end;
+}

src/Apps/W1/Sustainability/app/src/EUDR/EUDRLotNoInformation.TableExt.al

@@ -0,0 +1,75 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.Sustainability.EUDR;
+
+using Microsoft.Foundation.Address;
+using Microsoft.Inventory.Tracking;
+
+tableextension 6288 "EUDR Lot No. Information" extends "Lot No. Information"
+{
+    fields
+    {
+        field(6210; "EUDR Certificate No."; Code[50])
+        {
+            Caption = 'EUDR Certificate No.';
+            ToolTip = 'Specifies the certificate number that documents EUDR compliance for this lot.';
+            DataClassification = CustomerContent;
+        }
+        field(6211; "Certification Scheme"; Text[100])
+        {
+            Caption = 'Certification Scheme';
+            ToolTip = 'Specifies the certification scheme that applies to this lot, such as FSC, PEFC, RSPO, Rainforest Alliance, or Fairtrade.';
+            DataClassification = CustomerContent;
+        }
+        field(6212; "EUDR Valid From"; Date)
+        {
+            Caption = 'Valid From';
+            ToolTip = 'Specifies the first date that the EUDR certificate is valid for this lot.';
+            DataClassification = CustomerContent;
+
+            trigger OnValidate()
+            begin
+                if (Rec."EUDR Valid From" <> 0D) and (Rec."EUDR Valid To" <> 0D) then
+                    if Rec."EUDR Valid From" > Rec."EUDR Valid To" then
+                        Error(EUDRValidFromAfterValidToErr, Rec.FieldCaption("EUDR Valid From"), Rec.FieldCaption("EUDR Valid To"));
+            end;
+        }
+        field(6213; "EUDR Valid To"; Date)
+        {
+            Caption = 'Valid To';
+            ToolTip = 'Specifies the last date that the EUDR certificate is valid for this lot.';
+            DataClassification = CustomerContent;
+
+            trigger OnValidate()
+            begin
+                if (Rec."EUDR Valid From" <> 0D) and (Rec."EUDR Valid To" <> 0D) then
+                    if Rec."EUDR Valid To" < Rec."EUDR Valid From" then
+                        Error(EUDRValidFromAfterValidToErr, Rec.FieldCaption("EUDR Valid From"), Rec.FieldCaption("EUDR Valid To"));
+            end;
+        }
+        field(6214; "Country/Region of Prod. Code"; Code[10])
+        {
+            Caption = 'Country/Region of Production Code';
+            TableRelation = "Country/Region";
+            ToolTip = 'Specifies the country or region where the goods in this lot were produced. You can change the value if the distributor provides different origin information.';
+            DataClassification = CustomerContent;
+        }
+        field(6215; "DDS Reference Number"; Code[50])
+        {
+            Caption = 'DDS Reference Number';
+            ToolTip = 'Specifies the reference number issued when the due diligence statement is registered in the EU Information System, TRACES.';
+            DataClassification = CustomerContent;
+        }
+        field(6216; "DDS Verification No."; Code[50])
+        {
+            Caption = 'DDS Verification No.';
+            ToolTip = 'Specifies the verification number for the EUDR due diligence statement.';
+            DataClassification = CustomerContent;
+        }
+    }
+
+    var
+        EUDRValidFromAfterValidToErr: Label '%1 must not be after %2.', Comment = '%1 = Valid From field caption, %2 = Valid To field caption';
+}