fix: use source lists for extraction on Windows

.github/workflows/ci.yaml

@@ -90,3 +90,7 @@ jobs:
         working-directory: examples/simple
         shell: bash
         run: bazel run "@rules_formatjs//cli" -- --version
+
+      - name: Extract messages from a large source list
+        shell: bash
+        run: bazel test //tests/arguments:large_source_list_test

formatjs/extract.bzl

@@ -46,7 +46,6 @@ def _formatjs_extract_impl(ctx):
     # Build arguments for formatjs CLI
     args = ctx.actions.args()
     args.add("extract")
-    args.add_all(ctx.files.srcs)
     args.add("--out-file", out_file)
 
     if ctx.attr.format:
@@ -79,10 +78,16 @@ def _formatjs_extract_impl(ctx):
     if ctx.attr.flatten:
         args.add("--flatten")
 
+    # Keep source lists below Windows command-line limits.
+    sources = ctx.actions.args()
+    sources.add_all(ctx.files.srcs)
+    sources.set_param_file_format("multiline")
+    sources.use_param_file("--in-file=%s", use_always = True)
+
     # Run formatjs extract (v0.1.1+ sorts keys by default)
     ctx.actions.run(
         executable = formatjs_cli_info.cli,
-        arguments = [args],
+        arguments = [args, sources],
         inputs = depset(ctx.files.srcs),
         outputs = [out_file],
         mnemonic = "FormatjsExtract",

tests/arguments/BUILD.bazel

@@ -1,6 +1,8 @@
+load("@bazel_lib//lib:diff_test.bzl", "diff_test")
 load("@bazel_lib//lib:write_source_files.bzl", "write_source_files")
 load("@rules_formatjs//formatjs:compile.bzl", "formatjs_compile")
 load("@rules_formatjs//formatjs:extract.bzl", "formatjs_extract")
+load(":large_sources.bzl", "large_sources")
 
 # Test basic extraction with default settings
 formatjs_extract(
@@ -126,3 +128,20 @@ write_source_files(
         "fixtures/compiled_multiple.json": ":compiled_multiple",
     },
 )
+
+large_sources(
+    name = "large_sources",
+    src = "test.tsx",
+)
+
+formatjs_extract(
+    name = "messages_large_source_list",
+    srcs = [":large_sources"],
+    id_interpolation_pattern = "[sha512:contenthash:base64:6]",
+)
+
+diff_test(
+    name = "large_source_list_test",
+    file1 = "fixtures/messages_default.json",
+    file2 = ":messages_large_source_list",
+)

tests/arguments/large_sources.bzl

@@ -0,0 +1,18 @@
+"""Source inputs large enough to exceed Windows command-line limits."""
+
+def _large_sources_impl(ctx):
+    outputs = []
+    for index in range(512):
+        output = ctx.actions.declare_file("sources with spaces/source_{}.tsx".format(index))
+        ctx.actions.expand_template(
+            template = ctx.file.src,
+            output = output,
+            substitutions = {},
+        )
+        outputs.append(output)
+    return [DefaultInfo(files = depset(outputs))]
+
+large_sources = rule(
+    implementation = _large_sources_impl,
+    attrs = {"src": attr.label(allow_single_file = True, mandatory = True)},
+)