Process Settings notifications off the posting thread

Summary:
`SettingsManager` cleans the entire user-defaults dictionary inline whenever a defaults change notification arrives. A write on the main thread therefore performs unrelated, potentially expensive work before returning.

Process these notifications on a serial background method queue. Coalesce pending notifications to the latest defaults state, while allowing a notification during a snapshot to schedule a trailing update. Keep JavaScript mutations on the same queue and suppress their notifications at posting time. Drop queued work after invalidation without blocking teardown or retaining the module.

The `settingsUpdated` event name and full JSON-cleaned payload remain unchanged. Rapid external changes may be reported as one latest-state update rather than separate intermediate transitions. Synchronous constants export is unchanged.

Changelog:
[iOS][Fixed] - Avoid blocking user-defaults writers while processing Settings change notifications

Differential Revision: D124504338

Author: Abbondanzo

packages/react-native/Libraries/Settings/RCTSettingsManager.mm

@@ -11,16 +11,22 @@
 #import <React/RCTBridge.h>
 #import <React/RCTConvert.h>
 #import <React/RCTEventDispatcherProtocol.h>
+#import <React/RCTInvalidating.h>
 #import <React/RCTUtils.h>
 
+#include <atomic>
+
 #import "RCTSettingsPlugins.h"
 
-@interface RCTSettingsManager () <NativeSettingsManagerSpec>
+@interface RCTSettingsManager () <NativeSettingsManagerSpec, RCTInvalidating>
 @end
 
 @implementation RCTSettingsManager {
-  BOOL _ignoringUpdates;
+  std::atomic<bool> _ignoringUpdates;
+  std::atomic<bool> _updateScheduled;
+  std::atomic<bool> _invalidated;
   NSUserDefaults *_defaults;
+  dispatch_queue_t _methodQueue;
 }
 
 @synthesize moduleRegistry = _moduleRegistry;
@@ -40,7 +46,11 @@ - (instancetype)init
 - (instancetype)initWithUserDefaults:(NSUserDefaults *)defaults
 {
   if ((self = [super init]) != nullptr) {
+    _ignoringUpdates = false;
+    _updateScheduled = false;
+    _invalidated = false;
     _defaults = defaults;
+    _methodQueue = dispatch_queue_create("com.facebook.react.SettingsManager", DISPATCH_QUEUE_SERIAL);
 
     [[NSNotificationCenter defaultCenter] addObserver:self
                                              selector:@selector(userDefaultsDidChange:)
@@ -61,18 +71,47 @@ - (instancetype)initWithUserDefaults:(NSUserDefaults *)defaults
       {.settings = RCTJSONClean([_defaults dictionaryRepresentation])});
 }
 
+- (dispatch_queue_t)methodQueue
+{
+  return _methodQueue;
+}
+
+- (void)invalidate
+{
+  _invalidated = true;
+  [[NSNotificationCenter defaultCenter] removeObserver:self name:NSUserDefaultsDidChangeNotification object:_defaults];
+}
+
 - (void)userDefaultsDidChange:(NSNotification *)note
 {
-  if (_ignoringUpdates) {
+  if (_ignoringUpdates || _invalidated || _updateScheduled.exchange(true)) {
     return;
   }
 
+  __weak RCTSettingsManager *weakSelf = self;
+  dispatch_async(_methodQueue, ^{
+    RCTSettingsManager *strongSelf = weakSelf;
+    if (strongSelf == nil) {
+      return;
+    }
+
+    // Clear before reading so a notification during the snapshot schedules a trailing update.
+    strongSelf->_updateScheduled = false;
+    if (strongSelf->_invalidated) {
+      return;
+    }
+
+    NSDictionary *settings = RCTJSONClean([strongSelf->_defaults dictionaryRepresentation]);
+    if (strongSelf->_invalidated) {
+      return;
+    }
+
 #pragma clang diagnostic push
 #pragma clang diagnostic ignored "-Wdeprecated-declarations"
-  [[_moduleRegistry moduleForName:"EventDispatcher"]
-      sendDeviceEventWithName:@"settingsUpdated"
-                         body:RCTJSONClean([_defaults dictionaryRepresentation])];
+    [[strongSelf->_moduleRegistry moduleForName:"EventDispatcher"] sendDeviceEventWithName:@"settingsUpdated"
+                                                                                      body:settings];
 #pragma clang diagnostic pop
+  });
 }
 
 /**