MatrixCompressor/CMakeLists.txt at develop · panda-official/MatrixCompressor · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
cmake_minimum_required(VERSION 3.16)

project(matrix_compressor VERSION 0.2.0)

# Options
option(MC_BUILD_TESTS "Build unit tests" OFF)
option(MC_BUILD_EXAMPLES "Build examples" OFF)
option(MC_BUILD_BENCHMARKS "Build benchmarks" OFF)

find_package(blaze REQUIRED)
find_package(Catch2 REQUIRED)

# Dependencies
include(FetchContent)

fetchcontent_declare(
    streamvbyte
    GIT_REPOSITORY https://github.com/lemire/streamvbyte.git
    GIT_TAG 7da04c7df63681a47f34a47ab457d6527825adbc
)

fetchcontent_declare(
    fpzip
    GIT_REPOSITORY https://github.com/victor1234/fpzip.git
    GIT_TAG drift-637
)

fetchcontent_makeavailable(streamvbyte)
fetchcontent_makeavailable(fpzip)

# Create target
set(MC_TARGET_NAME ${PROJECT_NAME})
add_library(${MC_TARGET_NAME} sources/matrix_compressor.cpp)

# Add alias
add_library(${MC_TARGET_NAME}::${MC_TARGET_NAME} ALIAS ${MC_TARGET_NAME})

# Set fPIC
set_target_properties(${MC_TARGET_NAME} PROPERTIES POSITION_INDEPENDENT_CODE ON)
set_target_properties(streamvbyte PROPERTIES POSITION_INDEPENDENT_CODE ON)
set_target_properties(fpzip PROPERTIES POSITION_INDEPENDENT_CODE ON)

# Set compiler features
target_compile_features(${MC_TARGET_NAME} PUBLIC cxx_std_17)
set_target_properties(${MC_TARGET_NAME} PROPERTIES CXX_STANDARD_REQUIRED ON)

# Include paths
target_include_directories(
    ${MC_TARGET_NAME}
    PUBLIC
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)

# Link dependencies
target_link_libraries(${MC_TARGET_NAME} PUBLIC blaze::blaze)
target_link_libraries(${MC_TARGET_NAME} PRIVATE streamvbyte)
target_link_libraries(${MC_TARGET_NAME} PRIVATE fpzip)

if(MC_BUILD_EXAMPLES)
    message(STATUS "Examples enabled")
    add_subdirectory(examples)
endif()

include(CTest)
if(MC_BUILD_TESTS)
    message(STATUS "Unit tests enabled")
    add_subdirectory(tests)
endif()

if(MC_BUILD_BENCHMARKS)
    message(STATUS "Benchmarks enabled")
    add_subdirectory(benchmarks)
endif()

# Install rules
include(GNUInstallDirs)

# Create package targets file
install(TARGETS ${MC_TARGET_NAME} streamvbyte EXPORT ${MC_TARGET_NAME}-target)
install(
    EXPORT ${MC_TARGET_NAME}-target
    FILE ${MC_TARGET_NAME}-targets.cmake
    NAMESPACE ${MC_TARGET_NAME}::
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake
)

include(CMakePackageConfigHelpers)

# Create package config file
configure_package_config_file(
    "${PROJECT_SOURCE_DIR}/cmake/${MC_TARGET_NAME}-config.cmake.in"
    "${MC_TARGET_NAME}-config.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake
)
# Create package version file
write_basic_package_version_file(
    ${MC_TARGET_NAME}-config-version.cmake
    COMPATIBILITY ExactVersion
)

# Install cmake files
install(
    FILES
        "${PROJECT_BINARY_DIR}/${MC_TARGET_NAME}-config.cmake"
        "${PROJECT_BINARY_DIR}/${MC_TARGET_NAME}-config-version.cmake"
    DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/${PROJECT_NAME}/cmake
)

# Install headers
install(
    DIRECTORY ${PROJECT_SOURCE_DIR}/matrix_compressor
    TYPE INCLUDE
    PATTERN "*.md"
    EXCLUDE
)