Respect caller CMake settings while retaining the C++11 minimum (#465)

* Use cache variables to customize

Use cache variables in CMakeLists.txt to customize build settings.

* Respect caller CMake settings and preserve the C++11 minimum

---------

Co-authored-by: Benjamin Sergeant <benjamin.sergeant@applovin.com>

Author: hotwatermorning

CMakeLists.txt

@@ -6,12 +6,26 @@
 cmake_minimum_required(VERSION 3.4.1...3.17.2)
 set(CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/CMake;${CMAKE_MODULE_PATH}")
 
+# Set the default before project() initializes this cache entry.
+if (NOT DEFINED CMAKE_EXPORT_COMPILE_COMMANDS AND
+    NOT DEFINED ENV{CMAKE_EXPORT_COMPILE_COMMANDS})
+  set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
+endif()
+
 project(ixwebsocket LANGUAGES C CXX VERSION 12.1.0)
 
-set (CMAKE_CXX_STANDARD 11)
-set (CXX_STANDARD_REQUIRED ON)
-set (CMAKE_CXX_EXTENSIONS OFF)
-set (CMAKE_EXPORT_COMPILE_COMMANDS yes)
+if (NOT DEFINED CMAKE_CXX_STANDARD)
+  set(CMAKE_CXX_STANDARD 11)
+endif()
+if (CMAKE_CXX_STANDARD STREQUAL "98" OR CMAKE_CXX_STANDARD LESS 11)
+  message(FATAL_ERROR "IXWebSocket requires C++11 or later")
+endif()
+if (NOT DEFINED CMAKE_CXX_STANDARD_REQUIRED)
+  set(CMAKE_CXX_STANDARD_REQUIRED ON)
+endif()
+if (NOT DEFINED CMAKE_CXX_EXTENSIONS)
+  set(CMAKE_CXX_EXTENSIONS OFF)
+endif()
 
 option (BUILD_DEMO OFF)
 

docs/build.md

@@ -59,6 +59,13 @@ Autobahn protocol compliance checks run in Docker with
 the CI check; it also runs on `master` and manually. See the
 [Autobahn instructions](autobahn.md) for reports and local debugging.
 
+The library defaults to C++11 and requires C++11 or later. To build with a newer
+standard, pass `-DCMAKE_CXX_STANDARD=17` (or another supported standard). The CLI
+and tests inherit this choice; the test framework requires at least C++14.
+Caller-provided `CMAKE_CXX_STANDARD_REQUIRED`, `CMAKE_CXX_EXTENSIONS`, and
+`CMAKE_EXPORT_COMPILE_COMMANDS` settings are respected, including values inherited
+from a parent project using `add_subdirectory`.
+
 Options for building:
 
 * `-DBUILD_SHARED_LIBS=ON` will build the unittest as a shared libary instead of a static library, which is the default

test/CMakeLists.txt

@@ -5,8 +5,6 @@
 cmake_minimum_required (VERSION 3.14)
 project (ixwebsocket_unittest)
 
-set (CMAKE_CXX_STANDARD 11)
-
 option(USE_TLS "Add TLS support" ON)
 
 # Shared sources
@@ -119,6 +117,13 @@ foreach(TEST_TARGET_NAME ${TEST_TARGET_NAMES})
 
 endforeach()
 
+add_test(NAME IXWebSocketBuildSettings
+  COMMAND ${CMAKE_COMMAND}
+    -S ${CMAKE_CURRENT_SOURCE_DIR}/cmake/build-settings
+    -B ${CMAKE_CURRENT_BINARY_DIR}/cmake-build-settings
+    -G "${CMAKE_GENERATOR}")
+set_tests_properties(IXWebSocketBuildSettings PROPERTIES TIMEOUT 30)
+
 set_tests_properties(IXWebSocketReconnectTest IXWebSocketDispatchTest IXWebSocketSendFailureTest PROPERTIES TIMEOUT 30)
 
 if (USE_NETWORK_FRAMEWORK OR (UNIX AND USE_TLS AND (USE_OPEN_SSL OR USE_LIBRE_SSL OR USE_MBED_TLS)))

test/cmake/build-settings/CMakeLists.txt

@@ -0,0 +1,30 @@
+cmake_minimum_required(VERSION 3.14)
+
+# Normal parent variables must take precedence over defaults in the dependency.
+set(CMAKE_CXX_STANDARD 17)
+set(CMAKE_CXX_STANDARD_REQUIRED OFF)
+set(CMAKE_CXX_EXTENSIONS ON)
+set(CMAKE_EXPORT_COMPILE_COMMANDS OFF)
+project(ixwebsocket_build_settings LANGUAGES C CXX)
+
+set(USE_TLS OFF CACHE BOOL "")
+set(USE_ZLIB OFF CACHE BOOL "")
+set(USE_WS ON CACHE BOOL "")
+set(USE_TEST ON CACHE BOOL "")
+add_subdirectory(../../.. ixwebsocket)
+
+foreach(target ixwebsocket ws IXHttpTest)
+  get_target_property(standard ${target} CXX_STANDARD)
+  get_target_property(required ${target} CXX_STANDARD_REQUIRED)
+  get_target_property(extensions ${target} CXX_EXTENSIONS)
+  if (NOT standard STREQUAL "17" OR required OR NOT extensions)
+    message(FATAL_ERROR "${target} changed the parent settings: ${standard};${required};${extensions}")
+  endif()
+endforeach()
+
+get_target_property(library_source ixwebsocket SOURCE_DIR)
+get_directory_property(export_commands DIRECTORY ${library_source}
+  DEFINITION CMAKE_EXPORT_COMPILE_COMMANDS)
+if (export_commands)
+  message(FATAL_ERROR "IXWebSocket enabled compile commands despite the parent setting")
+endif()

ws/CMakeLists.txt

@@ -6,8 +6,6 @@
 cmake_minimum_required (VERSION 3.14)
 project (ws)
 
-set (CMAKE_CXX_STANDARD 11)
-
 option(USE_TLS "Add TLS support" ON)
 
 include_directories(ws .)